;Program: Hrací kostka
;*********************************
	LIST P = 16F84,	R = DEC
	#INCLUDE <P16F84.INC>
;--------------------------------- 
 __CONFIG   _CP_OFF & _WDT_OFF & _PWRTE_ON & _XT_OSC
;****************************************************************************
RAM	EQU	H'0C'
RBF	EQU	RAM
RBF1	EQU	RAM+1
NUM	EQU	RAM+2
NUM1	EQU	RAM+3
TMP	EQU	RAM+4
TM0	EQU	RAM+5
TM1	EQU	RAM+6
TM2	EQU	RAM+7
CISLO	EQU	RAM+8

#define	Q	PORTB,0
#define	RS	PORTB,1	
#define	RW	PORTB,2
#define	E	PORTB,3
#define	BF	RBF,3
#define ZVUK	PORTB,4
;xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

	ORG	0
	GOTO	START

;****************************************************************************
;PODPROGRAMY
;****************************************************************************

INILCD	CALL	t15mS		;doba 15 milisekund
	BCF	RS
	BCF	RW
	CALL	A_OUT		;port A výstup
	BSF	E
	MOVLW	B'00000011'
	MOVWF	PORTA
	BCF	E
	CALL	t4mS		;doba 4 milisekund
	BSF	E
	MOVLW	B'00000011'
	MOVWF	PORTA
	BCF	E
	CALL	t100uS		;doba 100 mikrosekund
	BSF	E
	MOVLW	B'00000011'
	MOVWF	PORTA
	BCF	E
	CALL	t100uS		;doba 100 mikrosekund
	MOVLW	B'00101000'
	CALL	WRPRI		;4.bitová komunikace a dva řádky
	MOVLW	B'00001000'
	CALL	WRPRI		;displej OFF
	MOVLW	B'00001100'
	CALL	WRPRI		;displej ON, kurzor OFF, blikání OFF
	MOVLW	B'00000110'
	CALL	WRPRI		;inkrementace, normální operace
	RETURN
;----------------------------------------------------------------------------
WRDATA	BSF	RS		;nastavení bitu RS pro zápis dat
	GOTO	$+2
WRPRI	BCF	RS		;nastavení bitů RS a RW pro zápis příkazu
	BCF	RW
	MOVWF	TMP		;číslo příkazu nebo data do registru TMP
	CALL	A_OUT		;portA jako výstup
	SWAPF	TMP,W		;horní 4 bity do registru W
	BSF	E
	MOVWF	PORTA		;zápis 4 horních bitů do displeje
	BCF	E
	MOVFW	TMP		;obsah registru TMP do registru W
	BSF	E
	MOVWF	PORTA		;zápis dolních 4 bitů do displeje
	BCF	E
	CALL	T_BF		;testování bitu BF
	RETURN
;----------------------------------------------------------------------------
T_BF	BCF	RS		;podprogram testuje konec operace (bit BF)
	BSF	RW
	CALL	A_IN		;portA vstup (po ukončení zase výstup)
	BSF	E
	MOVFW	PORTA
	MOVWF	RBF
	BCF	E
	NOP
	BSF	E
	MOVFW	PORTA
	MOVWF	RBF1
	BCF	E
	BTFSC	BF		;je bit BF=0 ? (0 = konec operace)
	GOTO	$-10		;ne - testuj znova
;----------------------------------------------------------------------------
A_OUT	MOVLW	B'11110000'	;pin A0/A3 výstup, pin A4 vstup
	GOTO	$+2
A_IN	MOVLW	B'11111111'	;pin A0/A7 vstup
	BSF	STATUS,RP0	;banka 1
	MOVWF	TRISA		;nastavení portu A
	BCF	STATUS,RP0	;banka 0
	RETURN
;****************************************************************************
t15mS	MOVLW	49		;doba 15 milisekund
	GOTO	$+2
t4mS	MOVLW	14		;doba 4 milisekund
	MOVWF	TM1
	MOVLW	255
	MOVWF	TM2
	DECFSZ	TM2,F
	GOTO	$-1
	DECFSZ	TM1,F
	GOTO	$-5
	RETURN
;----------------------------------------------------------------------------
t100uS	MOVLW	83		;doba 100 mikrosekund
	MOVWF	TM1
	DECFSZ	TM1,F
	GOTO	$-1
	RETURN
;****************************************************************************
t500mS	CLRF	TM2
	CLRF	TM1
	NOP
	DECFSZ	TM1,F
	GOTO	$-2
	NOP
	DECFSZ	TM1,F
	GOTO	$-2
	DECFSZ	TM2,F
	GOTO	$-7
	RETURN
;****************************************************************************
PIP	MOVLW	30		;pípnutí při stisku klávesy
	MOVWF	TM2
	BSF	ZVUK
	CALL	PIP1
	BCF	ZVUK
	CALL	PIP1
	DECFSZ	TM2,F
	GOTO	$-5
	RETURN
;--------------------------
PIP1	MOVLW	100
	MOVWF	TM0
	MOVLW	150
	MOVWF	TM1
	DECFSZ	TM1,F
	GOTO	$-1
	DECFSZ	TM0,F
	GOTO	$-1
	RETURN
;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
;PROGRAM
;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
START	BSF	STATUS,RP0	;banka 1
	MOVLW	B'11100001'
	MOVWF	TRISB		;nastavení portu B
	MOVLW	B'11001000'
	MOVWF	OPTION_REG	;nastavení registru OPTION_REG
	BCF	STATUS,RP0	;banka 0
	CALL	INILCD		;inicializace displeje
	MOVLW	1
	CALL	WRPRI		;reset displeje

	MOVLW	133
	CALL	WRPRI		;adresa DDRAM displeje
	MOVLW	126
	CALL	WRDATA		;tisk šipky doprava
	MOVLW	32
	CALL	WRDATA		;tisk mezery
	MOVLW	63
	CALL	WRDATA		;tisk "?"
	MOVLW	32
	CALL	WRDATA		;tisk mezery
	MOVLW	127
	CALL	WRDATA		;tisk šipky doleva

ZAS	CLRF	PORTA
	BTFSS	Q		;je stisknuto tlačítko ENTER?
	GOTO	$-1		;ne,tak testuj znovu

	MOVLW	135
	CALL	WRPRI		;adresa DDRAM displeje
	MOVLW	32
	CALL	WRDATA		;tisk mezery

	MOVFW	TMR0		;obsah TMR0 do W
	ANDLW	B'00000111'	;úprava registru W
	MOVWF	CISLO		;obsah W do registru CISLO

	CALL	PIP		;pípnutí
	CALL	t500mS		;doba 500 milisekund

	MOVLW	135
	CALL	WRPRI		;adresa DDRAM displeje
	CALL	KODER		;podprogram KODER

	CALL	WRDATA		;tisk výsledku
	GOTO	ZAS		;jdi na ZAS

;****************************************************************************
	ORG	768	;adresa programové paměti
KODER	MOVLW	3
	MOVWF	PCLATH	;číslo 3 do registru PCLATH
	MOVFW	CISLO
	ADDWF	PCL,F	;proveden skok dle obsahu registru CISLO
	RETLW	49	;"1"
	RETLW	50	;"2"
	RETLW	51	;"3"
	RETLW	52	;"4"
	RETLW	53	;"5"
	RETLW	54	;"6"
	RETLW	42	;"*"
	RETLW	42	;"*"
;****************************************************************************
	END
